///////////////////////////////////////////////////////////////////////////
// "Growth of torsion groups of elliptic curves upon base changes"
// Enrique González-Jiménez & Filip Najman
///////////////////////////////////////////////////////////////////////////

// 13/10/2016 - Magma 2.21

// Magma script related to Theorem7.7

// Elliptic curve E_t (see Zywina's Theorem 1.5 (iv))
K<t>:=FunctionField(Rationals());
Kx<x>:=PolynomialRing(K);
A:=-27*(t^2-t+1)*(t^6+229*t^5+270*t^4-1695*t^3+1430*t^2-235*t+1);
B:=54*(t^12-522*t^11-8955*t^10+37950*t^9-70998*t^8+131562*t^7-253239*t^6+316290*t^5-218058*t^4+80090*t^3-14631*t^2+510*t+1);
H41_7:=[A,B];

Et:=EllipticCurve(H41_7);

/* OUTPUT: Generically the torsion subgroup of Et is trivial
>TorsionSubgroup(Et); 
Abelian Group of order 1
Mapping from: Abelian Group of order 1 to CrvEll: Et given by a rule [no 
inverse]
*/


// 7-division polynomial of Et
P7:=DivisionPolynomial(Et,7);
// Factorization of the 7-division polynomial of Et
L7:=Factorization(P7);

/* OUTPUT: The degree of the factors of the 7-division polynomial of Et
> [Degree(p[1]) : p in L7];
[ 3, 7, 7, 7 ]
*/


// For any degree 7 factor of the 7-division polynomial we build an extension of degree 7 over Q(t)

K2<a2>:=quo<Kx | L7[2][1]>;
K3<a3>:=quo<Kx | L7[3][1]>;
K4<a4>:=quo<Kx | L7[4][1]>;

// We check that for the above degree 7 extensions of Q(t) we have a degree 7 point in Et.
for a in [*a2,a3,a4*] do
  boo:=IsSquare(a^3+A*a+B);
  boo;
end for;
/*
true
true
true
*/

// Now we check that, in fact, the three degree 7 extensions of Q(t) are the same:
L73_K2:=Factorization(Polynomial(K2,L7[3][1]));
L74_K2:=Factorization(Polynomial(K2,L7[4][1]));
/*
> [Degree(p[1]) : p in L73_K2];
[ 1, 6 ]
> [Degree(p[1]) : p in L74_K2];
[ 1, 6 ]
*/