///////////////////////////////////////////////////////////////////////////
// "Growth of torsion groups of elliptic curves upon base changes"
// Enrique González-Jiménez & Filip Najman
///////////////////////////////////////////////////////////////////////////

// 13/10/2016 - Magma 2.21

// Magma script related to Theorem7.1

Z49:=Integers(49);
Z7:=Integers(7);
Sub:=[H`subgroup: H in Subgroups(GL(2,Z49))];

// Let G be a subgroup of GL(2,7) which acts on the left: M*v (M in G) 
// then we need to transpose to work in Magma 
// (since Magma the subgroups of GL(2,7) acts on the right: v*M (M in G) 


// 7B.1.1 is generated by {[1,0,0,3], [1,1,0,1]} in GL(2,7)
G7B11:=sub<GL(2,Z7) | {[1,0,0,3],[1,0,1,1]}>; // Transpose the generators on Sutherland/Zywina 

// 7B.1.3 is generated by {[1,0,0,3], [1,1,0,1]} in GL(2,7)
G7B13:=sub<GL(2,Z7) | {[3,0,0,1],[1,0,1,1]}>; // Transpose the generators on Sutherland/Zywina 


// Imm7B11 is the set of subgroups GG of GL(2,Z/49Z) (up to conjugation) such that GG = G (mod 7), where G=7B.1.1
Im_rho:=G7B11;
Imm7B11:=[H`subgroup: H in Subgroups(GL(2,Z49)) | IsConjugate(GL(2,Z7),sub<GL(2,Z7) | {GL(2,Z7)!m : m in Generators(H`subgroup)}>,Im_rho)];


// Imm7B13 is the set of subgroups GG of GL(2,Z/49Z) (up to conjugacy) such that GG = G (mod 7), where G=7B.1.3
Im_rho:=G7B13;
Imm7B13:=[H`subgroup: H in Subgroups(GL(2,Z49)) | IsConjugate(GL(2,Z7),sub<GL(2,Z7) | {GL(2,Z7)!m : m in Generators(H`subgroup)}>,Im_rho)];


// For any subgroup GG in Imm7B11 we compute:
//   for any v in (Z/49Z)^2 of order 49 
//   if the orbit G.v is of length 7,
//   and in that case we determine the Name of the Galois group of the corresponding number field of degree 7.  
G49_7B11:={};
for GG in Imm7B11 do
    V49:={ v : v in RSpace(GG) | not IsZero(v) and not &and[IsDivisibleBy(Eltseq(v)[1],7),IsDivisibleBy(Eltseq(v)[2],7)]}; 
    names:={GroupName(quo<GG | Core(GG,Stabiliser(GG,v))>) : v in V49 | #Orbit(GG,v) eq 7};
    G49_7B11:=G49_7B11 join names;
end for;

/* OUTPUT: For any subgroups GG in Imm7B111 and for any v in (Z/49Z)^2 of order 49 such that |G.v|=7 
we obtain that the corresponding number field of degree 7 is cyclic:

> G49_7B11;
{ C7 }
*/


// For any subgroup GG in Imm7B13 we compute:
//   for any v in (Z/49Z)^2 of order 49 
//   if the orbit G.v is of length 7,
//   and in that case we compute the Name of the Galois group of the corresponding number field of degree 7.
G49_7B13:={};
for GG in Imm7B13 do
    V49:={ v : v in RSpace(GG) | not IsZero(v) and not &and[IsDivisibleBy(Eltseq(v)[1],7),IsDivisibleBy(Eltseq(v)[2],7)]}; 
    names:={GroupName(quo<GG | Core(GG,Stabiliser(GG,v))>) : v in V49 | #Orbit(GG,v) eq 7};
    G49_7B13:=G49_7B13 join names;
end for;


/* OUTPUT: For any subgroups GG in Imm7B113 and for any v in (Z/49Z)^2 of order 49 we obtain |G.v| \ne 7:

> G49_7B13;
{}
*/