///////////////////////////////////////////////////////////////////////////
// "Growth of torsion groups of elliptic curves upon base changes"
// Enrique González-Jiménez & Filip Najman
///////////////////////////////////////////////////////////////////////////

// 13/10/2016 - Magma 2.21

// Magma script related to Lemma 8.16

load "2primary_Ss.txt";

function aux_Id(m,s)
// return true if Matrix m (mod 2^s) is congruent to the identity
  if [Integers(2^s)!t : t in Eltseq(m)] eq [1,0,0,1] then return true; else return false; end if;
end function;

function Cuenta(G,N,s,d)
// Given a group G that is the 2-adic image of an elliptic curve E over Q, 
// and three integers N>0, s>=0, d>0
// the function determines the (name of the) Galois Groups of the fields K such that E(K)[2]=Z/2^sZ x Z/2^NZ 
// and [K:Q] divides d.
 
  M:=Characteristic(BaseRing(G));
  GG:=sub<GL(2,Integers(2^N))|Generators(G),[[1,M,0,1],[1,0,M,1],[1+M,0,0,1],[1,0,0,1+M]]>;
  Odds:=[[i,j] : i in [0..2^N-1], j in [0..2^N-1] | IsOdd(i) or IsOdd(j)]; 
  L:={};
  V := RSpace(GG);
S:=[];
  for v in Odds do
    Hv := Stabiliser(GG,V!v);
    Hvmod2s:=[m : m in Hv | aux_Id(m,s)]; 
    HHv:=sub<GL(2,Integers(2^N))|Hvmod2s>;
    ord_s:=#Hvmod2s;
    hv:=Integers()!(Order(GG)/ord_s);
    if IsDivisibleBy(d,hv) then 
//    if hv eq d then
      Kv:=quo<GG | Core(GG,HHv)>;
      Gal:=GroupName(Kv);
      L:=L join {Gal};
    end if;
  end for;
  return L;
end function;




// Has C2 over Q and the torsion grows to C2xC8 over a quartic number field
// s=1
// N=3
// For each of the 2-adic images of an elliptic curve E over Q (from the Rouse and Zurieck-Brown database)
// such that E(Q)[2]=C2 and E(K)[2^\infty]=C2xC8 where [K:Q] divides 4 we determine the Galois group of K over Q
d:=4;
LC:={};
for rzb in RZB do 
  T:=rzb[3]; 
  if (T[1][1] eq 1) and (T[1][2] ne 1) and (T[2][1] ne 1)  then // E(Q)[2]=C2
    if IsDivisibleBy(4,T[2][3]) then // C2xC8 defined over a quartic number field
      G:=sub<GL(2,Integers(rzb[2])) | {m : m in rzb[4]}>;
      CC:=Cuenta(G,3,1,d);
      LC:=LC join CC;
    end if;
  end if;
end for;
LC;

/* OUTPUT: 
Let E/Q an elliptic curve such that E(Q)[2]=C2. 
The Galois group of the fields K such that C2xC8 \subset E(K)
and [K:Q] divides 4 are:
{ C2^2 }
*/

// C4 subset E(Q), E(Q)[2] cyclic and the torsion grows to C2xC8 over a quartic number field
// s=1
// N=3
// For each of the 2-adic images of an elliptic curve E over Q (from the Rouse and Zurieck-Brown database)
// such that C4 subset E(Q) and E(K)[2]=C2xC8 where [K:Q] divides 4 we determine the Galois group of K

d:=4;
LC:={};
for rzb in RZB do
  T:=rzb[3]; 
  if (T[1][2] eq 1) and (T[2][1] ne 1)  then // C4 subset E(Q)[2^\infty] and E(Q)[2] cyclic
    if IsDivisibleBy(4,T[2][3]) then // C2xC8 defined over a quartic number field
      G:=sub<GL(2,Integers(rzb[2])) | {m : m in rzb[4]}>;
      CC:=Cuenta(G,3,1,d);
      LC:=LC join CC;
    end if;
  end if;
end for;
LC;

/* OUTPUT: Let E/Q an elliptic curve such that C4 subset E(Q)[2^\infty] and E(Q)[2] cyclic
The Galois group of the fields K such that C2xC8 \subset E(K)
and [K:Q] divides 4 are:

{ C4, C2^2, C2 }
*/

// C2xC2 subset E(Q) and the torsion grows to C2xC8 over quartic number field
// s=1
// N=3
// For each of the 2-adic images of an elliptic curve E over Q (from the Rouse and Zurieck-Brown database)
// such that C2xC2 subset E(Q) and E(K)[2]=C2xC8 where [K:Q] divides 4 we determine the Galois group of K
// and in the case that this Galois group is D4 we check that [Q(E[4]):Q]=4

d:=4;
LC:={}; LC4xC4:={};
for rzb in RZB do
  T:=rzb[3]; 
  if (T[2][1] eq 1) then // E(Q)[2]=E[2]
    if IsDivisibleBy(4,T[2][3]) then // C2xC8 defined over a quartic number field
      G:=sub<GL(2,Integers(rzb[2])) | {m : m in rzb[4]}>;
      CC:=Cuenta(G,3,1,d);
      if "D4" in CC then 
         LC4xC4:=LC4xC4 join {T[3][1]}; // Add [Q(E[4]):Q] to the set LC4xC4
      end if;
      LC:=LC join CC;
    end if;
  end if;
end for;
LC; LC4xC4;

/* OUTPUT
Let E/Q be an elliptic curve such that E(Q)[2]=E[2].
The Galois group of the fields K such that C2xC8 \subset E(K)
and [K:Q] divides 4 are:
> LC;
{ C1, C2^2, C2, D4 }
In the case D4 we have that the degree of the number fields 
Q(E[4]) are:
> LC4xC4;
{ 4 }
*/